Time is incorrectly treated when being pushed to notification body

1

Hi, I’ve noticed that if I calculate time and send it as notification path. this will not be displayed correctly.
At the same time, the same part of formula indicated exactly what I need.
The notification I get:
image
the formula I use:

"Last check performed at "+ 
totime([All morning checks].[Check time].last()) + 
"by " + 
[All morning checks].[Created By].last() +
". Everything is OK"

once I use formula below, time is displayed correctly:

totime([All morning checks].[Check time].last())

2

to be sure, that’s what i see in formula field:
image

3

the same applied to mentioned user name, by the way

4

Never concatenate strings together with +.

Use Concatenate():

Concatenate(
  "Last check performed at ",
  totime([All morning checks].[Check time].last()),
  "by ",
  [All morning checks].[Created By].last(),
  ". Everything is OK"
)

Or even better, Format():

Format(
  "Last check performed at {1} by {2}. Everything is OK",
  [All morning checks].[Check time].Last(),
  [All morning checks].[Created By].Last()
)

Also generally it’s a good idea to 1. .ToText() the time, and 2. dereference the actual .Name value of the person record you’re inserting:

Format(
  "Last check performed at {1} by {2}. Everything is OK",
  [All morning checks].[Check time].Last().ToText(),
  [All morning checks].[Created By].Last().Name
)
2 Likes
5

thank you. I’ve already found totext() function, but with Format() that looks much clearer.