A newbie trying to understand Button Formulas

[Pch]

Hi @Michael_Bartholomew !

I’ve created a sample based on your description . (You’ll find it below)

But first, the explanations .

@Michael_Bartholomew

the values in column B are updated to equal the values in column A. For example if I press Button 1, column B would update to show the value 5 where the value of column A was also 5

In my sample, this is done with the very first button named Copy_Button.
Its Action formula is this one :

[Example Table].FormulaMap(
  RunActions(
    ModifyRows(
      CurrentValue,
      B,CurrentValue.A
    )
  )
)

And what it does is :

It takes the table [Example Table] and for each row in the table (FormulaMap()) it runs this action (RunActions()) ModifyRows() :

• The row to modify here is represented by CurrentValue
  A table is in fact a list of rows and each row in the list of all rows is stored within CurrentValue. Each very specific value in your column C (for example) is stored as CurrentValue.C which Coda would display as just C in a formula)
• The column to modify is the column B ( CurrentValue.B)
  In other words, each specific value in the column B
• The new column value is CurrentValue.A
  I.e.: Each specific value in the “list of all rows” in the column A

Now for the buttons 2 and 3, they work in a similar way as the button 1 does …

@Michael_Bartholomew

• note: could this Button be automated such that it is pressed automatically once the action from manually pressing Button 2 has been completed?

It can be done, but you’ll need to set up your Button 3 before the Button 2 in order to use it in the Action formula of the Button 2.

In the Button 3 (named Clear_Button in my sample) the Action formula looks like this :

[Example Table].FormulaMap(
  RunActions(
    ModifyRows(
      CurrentValue,
      B,""
    )
  )
)

Kind of the same as the Button 1 but this time, it acts on B (CurrentValue.B) and replace each specific value in the column B by "" (Blank) .

And for the Button 2 (named Sum_Button)

RunActions(
[Example Table].FormulaMap(
  RunActions(
    ModifyRows(
      CurrentValue,
      C,C + B
    )
  )
),
Clear_Button)

This one runs 2 distinctive actions :

1. For each row in your table, it sums each specific value in the column C and each specific value in the column B (and the results appear for each row in the column C)

And then

2. It pushes the Button 3 (the Clear_Button)

This is not easy to explain (or to understand for that matter )… So, don’t hesitate, if you need more explanations .

In the meantime, I hope this helps !

PS: Oh and there’s a topic I created a while ago which helped me a lot with FormulaMap() (as I was stuck with this one ):

FormulaMap() : When and where?

Here is a small example. Imagine you have two tables (Table 1 and Table 2) and you want to copy all the row values from Table 1 to Table 2 (only from Name column in my example, but you can copy more columns). You can do it with a button using FormulaMap function. You “list” to use with the FormulaMap function will be all the rows in Table 1. Code for the button: [Table 1].FormulaMap(AddRow([Table 2],[Table 2].Name, ToText(CurrentValue))) Here is an example doc: Second button copies only …