Add new table row, modify existing row, then open new row

[Susan_M_Davis]

I have a button that adds a new row to a different table, then updates the current row of the current table. BUT…I’d like to then be able to open up the new row added to the other table for editing. I cannot think of any way to make this happen. If I modified the row first, then I could add the new row and open it for editing, but that would affect the data being sent to the new row. Any ideas?

[Pch]

Hi @Susan_M_Davis !

Maybe you could add to your table where you add the row a “properties” column Created On (which will indicate when the row was created) and then add an action in your button similar to this :

[ ... ]

OpenRow(
    [Add Row Here].Sort(true,[Add Row Here].[Created on]).Last()
    )

This should retrieve the last row created in the table and expand it …

The complete formula in my button is this one :
(See sample below )

RunActions(
  AddRow(
    [Add Row Here],
    [Add Row Here].Name,Concatenate("Test ", thisRow.Number + 1)
  ),
  ModifyRows(
    thisRow,
    thisRow.Number,
    thisRow.Number + 1
  ),
  OpenRow(
    [Add Row Here].Sort(true,[Add Row Here].[Created on]).Last()
    )
)

---

Or, you could separate the AddRow() and ModifyRows() actions from the OpenRow()… Keep your button as it is and add a distinctive button for OpenRow(). The 1st button (adding the row and modifying thisRow) could push the 2nd one using the same action formula as previously :

OpenRow(
    [Add Row Here 3].Sort(true,[Add Row Here 3].[Created on]).Last()
    )

Another possibility, probably more reliable than what’s above, you could use a checkbox instead of a [Created on] column to pin point the row the button just added to the table…
The action in the button would look like this :

RunActions(
  AddRow(
    [Add Row Here 2],
    [Add Row Here 2].Name,Concatenate("Test ", thisRow.Number + 1),
    [Add Row Here 2].[Is New],true
  ),
  ModifyRows(
    thisRow,
    thisRow.Number,
    thisRow.Number + 1
  ),
  OpenRow(
    [Add Row Here 2].Filter([Is New] = true)
  )
)

This should retrieve the row where the checkbox is checked and expand it …
In this case, to avoid errors, you would need to mark the checkbox as false once you’re done editing the row … Which can be done within a Close expanded row button …

Those are just ideas you could explore … and maybe others will have better suggestions …

[Agile_Dynamics]

i hadnt read this thread when i was posting this item (which might be slightly relevent)

Full-Screen Dialogs & Double-Linked Records

i had to crack two problems recently, and so i thought i would share the techniques Edit & Insert records into a table using a FULL SCREEN dialog Insert records into a table while linking the new record & the old record (Next & Previous links)

respect
max

[Susan_M_Davis]

Great ideas! Thank you all.