No help needed - Just a question to ask about : Concatenate() a list of sequential and/or non-sequential numbers?

Pch · October 4, 2020, 5:15pm

Hi All !!!

I know I’ve been away for quite some time (Life just happened ) but I always knew that, at some point, I would have the opportunity to get back on having fun building docs, and here, by the same occasion .

Well, this kind of happened a month ago (or so) when I began to create my very first personal doc since I went AWOL .

At some point, I evidently hit a wall but found a solution which works for that specific doc

So, completely out of curiosity (but also because I still need and want to learn ) I would like to know if I could have done this differently (and maybe in simpler way as I still tend to overcomplicate things where it’s not necessarily needed )

Any idea(s), would be more than appreciated !

I hope I shared this doc correctly (as it has been a while too) and didn’t make mistakes in the sharing options

I also really want to congratulate everyone for the magistral evolution of Coda !!!
Like the very first time I used Coda : The more I use it, the more ideas I get and therefore, the more I want to use it !
Plus, even though “my Coda” is a little bit rusty, I was more than happy to discover that I didn’t forgot that much during the months I was away and was still able to create a doc from scratch without too much trouble ! This, for me, says a lot about how great Coda is !

Thank you very much for reading !

jeo · October 4, 2020, 5:36pm

Welcome back @Pch, your presence was missed! Glad that you were able to circle back.

Please adjust the sharing permission on this doc. Right now other people cannot view your example

Brief history of how to share/embed in the Coda community (click to expand)

Pch · October 4, 2020, 5:45pm

Ahahah ! It should be working now !

Thank you very much for your help with sharing/embedding my doc ! And your very kind words too !

Paul_Danyliuk · October 5, 2020, 1:08pm

Hey @Pch, nice to see you back!

You got me curious and of course you overcomplicated it Here’s a much simpler solution:

Once you have your list of sorted numbers (Numbers (lists; sorted) in my doc), here are the steps:

Iterate over the list and remember positions of items that start a new range. For that, don’t iterate over the numbers themselves
```
Numbers.FormulaMap(CurrentValue...)
```
but iterate over indexes, i.e.
```
Sequence(1, Numbers.Count()).FormulaMap(
  Numbers.Nth(CurrentValue)...
)
```
To see where a new sublist starts, check if
```
.Nth(CurrentValue - 1) != .Nth(CurrentValue) - 1
```
Also append the Count + 1 value to the resulting list because we’ll need it for the next step.

The full formula:
```
Sequence(1, thisRow.Numbers.Count()).FormulaMap(
  If(
    thisRow.Numbers.Nth(CurrentValue - 1) = thisRow.Numbers.Nth(CurrentValue) - 1,
    List(),
    CurrentValue
  )
).ListCombine(thisRow.Numbers.Count() + 1)
```
See how we return List() instead of blank "" within the If() — ListCombine() would eat empty lists but not empty values.
Now that we have our “break points”, let’s collect a list of 2-item lists for each range’s start and end. If it’s a single-item list, both the start and the end are just going to be the same value:
```
Sequence(2, thisRow.Indexes.Count()).FormulaMap(
  List(
    thisRow.Numbers.Nth(thisRow.Indexes.Nth(CurrentValue - 1)),
    thisRow.Numbers.Nth(thisRow.Indexes.Nth(CurrentValue) - 1)
  )
)
```

Lastly, let’s just iterate over each range, format it with or without an arrow, and join together:

thisRow.[From-to pairs].FormulaMap(
  If(
    CurrentValue.First() = CurrentValue.Last(),
    CurrentValue.First(),
    Format(
      "{1} → {2}",
      CurrentValue.First(),
      CurrentValue.Last()
    )
  )
).Join(", ")

That’s how you break this calculation into logical steps. No need to calculate missing numbers, no need to compare each one with a different one or whatnot. Just left to right, N-th one with the (N-1)-th one. Collect ranges, then format ranges.

Jean_Pierre_Traets · October 5, 2020, 2:24pm

Wow @Paul_Danyliuk,

This is again a masterpiece of “formula fitness”

Thanks, not only for the solution, but even more to make it understandable for people like me

Pch · October 6, 2020, 11:49am

Ahahah ! I knew it !

FormulaMap() is a formula I actually have a hard time to “re-learn” how to use (correctly) and when. But I’m getting there !
I was pretty certain while building my example doc that I should’ve looked in that direction but I just couldn’t find a way around it…

This is, like always , a way better and prodigiously simpler solution to my initial problem !

Thank you very very very much for taking the time to look at this !
I’m gonna try and implement it to my doc right away !

Topic		Replies	Views
One on One In Person Coda Help - Docs, Tables & Templates structure Requests and Gigs	2	704	April 20, 2023
[Request] Need professional help with my Doc Requests and Gigs	2	723	July 5, 2020
Pay someone to build a coda doc?	4	248	July 3, 2023
Adhoc Coda support	4	202	December 11, 2023
How I explain Coda.io to my spreadsheet buddies. Would love honest feedback!	19	1041	November 16, 2021

No help needed - Just a question to ask about : Concatenate() a list of sequential and/or non-sequential numbers?

Related Topics